The case q=3 and nu=0 : guessing the three unknown series M(1), M'(1) and M"(1) (Section 13.1, continued)
> | subs(w=1,q=3,nu=0,eqM); |
The coefficient of t^n in M(x,y)
> | co:=proc(n) option remember: if n=0 then 1 else normal(x*y*(2*y+1)*add(co(i)*subs(x=1,co(n-1-i)),i=0..n-1) -x*y/(x-1)*(x*co(n-1)-subs(x=1,co(n-1))) -x*y*add(co(i)*subs(y=1,co(n-1-i)),i=0..n-1) +x*y/(y-1)*(y*co(n-1)-subs(y=1,co(n-1)))): fi: end: |
Let us guess whta is M(1)
> |
> | Liste:=[seq(subs(x=1,y=1,co(n)),n=0..40)]; |
> | with(gfun): |
> | ser:=listtoseries(Liste,t); |
> | with(numapprox); |
> | L:=[1,ser,ser^2,ser^3,ser^4]: |
> | hermite_pade(L,t,35); |
Conjectured equation for M(1)
> | algM1:=collect(1-2720*t^3-40*t+432*t^4+540*t^2+ M1*(-1+1712*t^3+42*t+9040*t^4-536*t^2-864*t^5)+ M1^2*(2040*t^3-14432*t^4-78*t^2-7200*t^5)+M1^3*(24000*t^5-1704*t^4)+M1^4*(-12500*t^6),M1,factor); |
> | degree(algM1,t); |
> | genus(algM1,t,M1); |
> | factor(parametrization(algM1,t,M1,S)); |
> | tS:=op(1,%); |
Changing the parametrization so that it has a nicer form: the new parametrization is the one that appears in Theorem 25
> | tS:=factor(subs(S=2+S,S=1/S,tS)); |
> | M1Ssol:=factor(solve(op(2,factor(subs(t=tS,algM1))),M1)); |
> | algS:=numer(t-tS); |
> | Sser:=op(2,algeqtoseries(algS,t,S,15,true)); |
> |
Guessing the series M'(1)
> | Liste:=[seq(subs(y=1,diff(subs(x=1,co(n)),y)),n=0..80)]: |
> | ser:=listtoseries(Liste,t): |
> | serS2:=series(subs(t=tS,ser),S,81); |
> | L:=[1,serS2,series(serS2^2,S,81)]: |
> | hermite_pade(L,S,80); |
The conjectured equation for M'(1)
> | algM2S:=op(1,%)+op(2,%)*M2+op(3,%)*M2^2; |
> | factor([solve(algM2S,M2)]); |
The conjectured expression for M'(1)
> | M2Ssol:=(1+2*S)*(32*S^12+32*S^11+12*S^10-32*S^9-16*S^8+18*S^7+14*S^6-28*S^5-58*S^4-49*S^3-25*S^2-7*S-1 +(1-2*S^3)*(4*S^2+2*S+1)*(1+S)^3*sqrt(Delta))/(2*S^3-1)^4/S^2; |
let su check the first coefficients
> | series(subs(Delta=(1+2*S)*(1+2*S+4*S^2),S=Sser,M2Ssol),t,15); |
> | [seq(subs(y=1,diff(subs(x=1,co(n)),y)),n=0..10)]; |
> |
> |
Guessing M"(1)
> | Liste:=[seq(subs(y=1,diff(subs(x=1,co(n)),y$2)),n=0..80)]: |
> | ser:=listtoseries(Liste,t): |
> | serS3:=series(subs(t=tS,ser),S,81); |
> | L:=[1,serS2,serS3]: |
> | factor(hermite_pade(L,S,81)); |
Conjectured equation for M"(1)
> | algM2M3S:=op(1,%)+op(2,%)*M2+op(3,%)*M3; |
Conjectured expression for M"(1)
> | M3Ssol:=collect(solve(subs(M2=M2Ssol,algM2M3S),M3),Delta,factor); |
Let us check
> | series(subs(Delta=(1+2*S)*(1+2*S+4*S^2),S=Sser,M3Ssol),t,15); |
> | [seq(subs(y=1,diff(subs(x=1,co(n)),y$2)),n=0..10)]; |
> |
> |
> |
> |
> |
> |