Construction of the two invariants (Section 6)
We have 4 equations, since the series Y_i cancel both the kernel Ker and the right-hand side R
> | e1:=subs(y=y1,Ker);e2:=subs(y=y2,Ker); |
> | e3:=subs(y=y1,R);e4:=subs(y=y2,R); |
We first solve e3 and e4 for x and M(x,1). (these are the two simplest equations).
Set xM(x,1)=S(x).
> | e3b:=subs(M(x,1)=Sx/x,e3); e4b:=subs(M(x,1)=Sx/x,e4); |
This is Eq. (34)
> | Sxsol1:=factor(solve(subs(isolate(e3b,x),e4b),Sx)); |
> | Xsol1:=factor(solve(subs(isolate(e3b,Sx),e4b),x)); |
The reciprocal of x looks nicer
> | Xinvsol1:=collect(1/Xsol1,M,factor); |
> |
Let us now work with e1 and e2
We eliminate M(x,1), and this gives another linear equation in x:
> | eqx1:=collect(op(3,factor(numer(subs(isolate(e1,M(x,1)),e2)))),x,factor); |
> | degree(%,x); |
Second expression of the recirpocal of x
> | Xinvsol2:=collect(1/solve(eqx1,x),M,factor); |
> |
> |
Compare these two epressions of 1/x : this will give the first invariant
> | collect((Xinvsol1-Xinvsol2),M,factor); |
> | eq5:=collect((Xinvsol1-Xinvsol2)/y1/y2*(y1-y2),M,factor); |
> | convert(op(3,eq5),parfrac,y1); |
> | convert(%,parfrac,y2); |
> | eq6:=subsop(3=%,eq5); |
> | factor(eq5/eq6); |
We can read off our first invariant:
> | I10:=y*w*t*q*M(1,y)-1/y+t/(y-1); |
Let us check
> | factor((subs(y=y1,I10)-subs(y=y2,I10))/eq6); |
We can just as well take
> | I1:=w*t*y*q*M(1,y)-(1-y)/y+t*y/(y-1); |
Indeed..
> | factor(I1-I10); |
> |
> |
Expression of M(1,y) in terms of the invariant I (denoted II). This is Eq. (36).
> | Mysol:=factor(isolate(I1-II,M(1,y))); |
We now derive from the equation e1 another expression of S(x):
> | Sxsol2:=factor(solve(subs(M(x,1)=Sx/x,x=1/Xinvsol2, subs(y=y1,Mysol),subs(y=y2,Mysol),e1),Sx)); |
...and compare it with the first expression of S(x) we have obtained:
> | eq7:=map(factor,collect(numer(factor(subs( subs(y=y1,Mysol),subs(y=y2,Mysol),Sxsol1-Sxsol2))),[y1,y2],distributed)); |
Compare with the equation in the paper (just above (37)) :
> | (nu-1)*(y1^2+y2^2-(q-2)*y1*y2)+y1*y2*(y1+y2)*((q+2*nu-2)*(II-2)+q*nu) +y1^2*y2^2*((q+nu-1)*II^2-(3*q+4*nu-4)*II+q*t*(w*q+nu-1)+2*q-q*(nu-1)+4*nu-4); |
> | factor(%/eq7); |
Replace y_i by 1/z_i
> | eq8:=map(factor,collect(numer(factor(subs(y1=1/z1,y2=1/z2,eq7))),[z1,z2],distributed)); |
> | collect(subs(z1=v1+a,z2=v2+a,eq8/(nu-1)),[v1,v2],distributed);; |
> | asol:=solve(coeff(coeff(%,v1,1),v2,0),a); |
Expression of the constant a given in the paper:
> | 1-((q+2*nu-2)*II-q)/(nu-1)/(4-q); |
> | factor(asol-%); |
> | eq9:=subs(Z=1,map(factor,collect(subs(z1=v1+asol,z2=v2+asol,Z*eq8/(nu-1)),[v1,v2],distributed))); |
Observe that the coefficient of v1v2 is -(q-2).
We will have to take the square root of:
> | DD:=collect(normal(-op(4,eq9)/q*(4-q)*(nu-1)^2),[II,t],factor); |
(Here, yinv stands for 1/y
> | UU:=(yinv-asol)*sqrt(4-q)*(nu-1)/sqrt(q)/sqrt(C); |
The value x where we will take T_m (x)
> | xsubs:=collect(factor(UU*sqrt(q)/2*sqrt(4-q)),[yinv,II],factor); |
Expression of x in the paper
> | ((nu-1)*(4-q)*(yinv-1)+(q+2*nu-2)*II-q)/2/sqrt(C); |
> | factor(xsubs-%); |
> |
> |